First off, to use this, every player cannot have NVGoggles as I overwrite the shortcut for them (plus they can use them + this script) so in each character do this:

Code:

this removeWeapon "NVGoggles";

In you init.sqf do this:

Code:

waitUntil { !isNil {player} };
waitUntil { player == player };
player setVariable ["NV", ["OFF", 0.02]];
player addAction ["Night Vision", "nightVision.sqf", [], 0, false, true, "nightVision", "_this == _target"];

and nightVision.sqf

Code:

_gen = _this select 0;
_caller = _this select 1;
_id = _this select 2;

_gen removeAction _id;

_NV = player getvariable "NV";
_NVOn = (_NV select 0);
_OldAperture = (_NV select 1);

if(_NVOn == "ON") 
exitwith
{
	setaperture -1;
	ppEffectDestroy ppColor;
	ppEffectDestroy ppBlur;
	player setvariable ["NV",["OFF",_oldAperture]];
	player addAction ["Night Vision", "nightVision.sqf", [], 0, false, true, "nightVision", "_this == _target"];
};

ppEffectDestroy ppColor;
ppEffectDestroy ppBlur;

ppColor = ppEffectCreate ["ColorCorrections", 1999];  
ppColor ppEffectEnable true;  
ppColor ppEffectAdjust [1, 1, 0, [0.4, 1, 0.4, 0], [0.4, 1, 0.4, 0.0], [0.4, 1, 0.4, 1.0]];  
ppColor ppEffectCommit 0;

ppBlur = ppEffectCreate ["dynamicBlur", 505];
ppBlur ppEffectEnable true;  
ppBlur ppEffectAdjust [.2];
ppBlur ppEffectCommit 0;

aperture = 0.0001;
while { aperture < _oldAperture } do
{
	aperture = aperture + 0.0005;
	setAperture aperture;
	sleep 0.001;
};


player setVariable ["NV", ["ON", _oldAperture]];

player addAction ["Night Vision", "nightVision.sqf", [], 0, false, true, "nightVision", "_this == _target"];
exit;

Lower the '0.02' value to make it brighter, raise it to make it darker

Code:

player setVariable ["NV", ["OFF", 0.02]];

Lower the '.2' value to make it less blurry, raise it to make it blurrier

Code:

ppBlur ppEffectAdjust [.2];

I am currently working on adding some key binds so players can manually adjust their aperture (the way it should be in game... not this auto adjusting crap that lowers the aperture to the point of making every a green nothingness if there is a light with 1km of you). After that, I'd like to actually add this to the NVGoggles.

You can call this by simply press N or rolling the mouse wheel to Night Vision.