RMM_f_backpack

Code:

// (C) Rommel, 
// http://creativecommons.org/licenses/by-nc-sa/2.5/au/
////////////////////////////////////////////////////

	if (isDedicated) exitwith {};
	
	_fReset = {
		BIS_MENU_GroupCommunication = [
			["User menu", false],
			["Open backpack", [2], "", -5, [["expression", "[0] spawn RMM_f_backpack"]], "1", "1"]
		];
	};

	_var = player getvariable "RMM_backpack";
	if (isnil {_var}) exitwith {
		player setvariable ["RMM_backpack", [[],[]], true];
	};
	if (count _this == 0) exitwith {
		[] call _fReset;
	};
	
	_invSlots = player call RMM_f_invSlots;

	_blackList = [
		"Binocular","CDF_dogtags","Cobalt_File","EvDogTags","Evkobalt","EvMap","EvMoney","EvMoscow","EvPhoto",
		"ItemCompass","ItemCore","ItemGPS","ItemMap","ItemRadio","ItemWatch","Kostey_photos","Kostey_map_case",
		"Kostey_notebook","Laserdesignator","Laserdesignator_mounted","Moscow_Bombing_File","NVGoggles"
	];
	_weapons = (weapons player) - _blackList;
	_magazines = magazines player;
	_weaponsMax = (_invSlots select 4) + (_invSlots select 6);
	_magazinesMax = (_invSlots select 2) + (_invSlots select 3);

	_switch = -1;
	if (count _this > 0) then {
		_switch = _this select 0;
	};

	_item = "";
	_itemType = -1;
	if (count _this > 1) then {
		_item = _this select 1;
		_cfgM = count (configFile>> "CfgMagazines" >> _item);
		_cfgW = count (configFile>> "CfgWeapons" >> _item);
		if (_cfgM > 0) then {
			_itemType = 1;
		} else {
			if (_cfgW > 0) then {
				_itemType = 0;
			};
		};
	};

	_idx = -1;
	if (count _this > 2) then {
		_idx = _this select 2;
	};

	_fHint = {
		_img = "CA\ui\data\ui_action_gear_ca.paa";
		_text = parsetext (
			format ["<t size='3.0' color='#ffffff' shadow='0'><img image='%1'/> Oh No!</t><br />", _img] +
			format ["<t size='0.9' color='#eeeeee' shadow = '1'>%1, a %2 cannot fit in your backpack!<br />Try removing something first.</t>", name player, _this]
		);
		hint _text;
	};
	_fHint2 = {
		_img = "CA\ui\data\ui_action_gear_ca.paa";
		_text = parsetext (
			format ["<t size='3.0' color='#ffffff' shadow='0'><img image='%1'/> Oh No!</t><br />", _img] +
			format ["<t size='0.9' color='#eeeeee' shadow = '1'>%1, a %2 cannot be carried as you are too heavy.<br />Try removing something first.</t>", name player, _this]
		);
		hint _text;
	};
	
	switch (_switch) do {
		case 0 : {
			_idx = 2;
			_weaponTypes = [];
			if (count (_var select 0) < _weaponsMax) then {
				{
					if (not (_x in _weaponTypes)) then {
						_weaponTypes set [count _weaponTypes, _x];
					};
				} foreach _weapons;
			};
			_magTypes = [];
			if (count (_var select 1) < _magazinesMax) then {
				{
					if (not (_x in _magTypes)) then {
						_magTypes set [count _magTypes, _x];
					};
				} foreach _magazines;
			};
			_Menu = [["User menu", false]];
			{
				_Menu set [count _Menu, [format["- Put in %1", _x], [_idx], "", -5, [["expression", format["[1, %1] spawn RMM_f_backpack", str(_x)]]], "1", "1"]];
				_idx = _idx + 1;
			} foreach (_magTypes + _weaponTypes);
			_ruckTypes = [];
			{
				if (not (_x in _ruckTypes)) then {
					_ruckTypes set [count _ruckTypes, _x];
				};
			} foreach ((_var select 0) + (_var select 1));
			{
				_Menu set [count _Menu, [format["- Take out %1", _x], [_idx], "", -5, [["expression", format["[2, %1] spawn RMM_f_backpack", str(_x)]]], "1", "1"]];
				_idx = _idx + 1;
			} foreach _ruckTypes;

			BIS_MENU_GroupCommunication = _Menu;
			showCommandingMenu "#USER:BIS_MENU_GroupCommunication";
			waituntil {speed player > 0};
			[] call _fReset;
		};
		case 1 : {
			_itemCount = if (_itemType == 0) then {count _weapons} else {count _magazines};
			_itemMax = if (_itemType == 0) then {_weaponsMax} else {_magazinesMax};
			if (_itemCount >= _itemMax) exitwith {_item call _fHint2};
			if (_item in (_weapons + _magazines)) then {
				_inRuck = _var select _itemType;
				if (count _inRuck < _itemMax) then {
					 if (_itemType == 0) then {player removeweapon _item} else {player removemagazine _item};
					_inRuck set [count _inRuck, _item];
					_var set [_itemType, _inRuck];
					player setvariable ["RMM_backpack", _var, true];
				} else {
					_item call _fHint;
				};
			};
			[0] call RMM_f_backpack;
		};
		case 2 : {
			_itemCount = if (_itemType == 0) then {count _weapons} else {count _magazines};
			_itemMax = if (_itemType == 0) then {_weaponsMax} else {_magazinesMax};
			if (_itemCount >= _itemMax) exitwith {_item call _fHint2};
			_inRuck = _var select _itemType;
			_idx = _inRuck find _item;
			if (_idx == -1) exitwith {};	
			_inRuck set [_idx, "^*&"];
			_inRuck = _inRuck - ["^*&"];
			_var set [_itemType, _inRuck];
			player setvariable ["RMM_backpack", _var, true];
			if (_itemType == 0) then {
				_primWeap = primaryWeapon player;
				if (_primWeap != "") then {
					[1, _primWeap] spawn RMM_f_backpack;
				};
				player addweapon _item;
			} else {
				player addmagazine _item;
			};
			[0] call RMM_f_backpack;
		};
	};

////////////////////////////////////////////////////

Ruck source

Code:

// (C) Rommel, 
// http://creativecommons.org/licenses/by-nc-sa/2.5/au/
////////////////////////////////////////////////////

	_gen = _this select 0;
	_caller = _this select 1;
	_id = _this select 2;
	
	if (_gen distance _caller > 3) exitwith {hint "You need to be closer.";};
	_gen removeaction _id;

	//_caller playMove "AinvPknlMstpSlayWrflDnon_medic";
	//sleep 8;

	hint "Press 0-8 to open your backpack";
	[] call RMM_f_backpack;
	
	sleep 10;
	_gen addaction ["Get a replacement backpack", "functions\ruckSource.sqf"];

////////////////////////////////////////////////////

Its only downside is the menu is a little clunky; and the menu may be over-ridden by COIN and SecOps. Which is why I may be developing a dialog for it in the near future. But for now, thats a working backpack which allows an extra weapon and ammunition to be stored (the maximums can be changed in the script easily).

RMM_f_invSlots

Code:

// (C) Rommel, 
// http://creativecommons.org/licenses/by-nc-sa/2.5/au/
////////////////////////////////////////////////////

	private ["_unit"];
	
	if (typename _this == "STRING") then {
		_unit = _this;
	} else {
		_unit = typeOf _this;
	};

	_int = getNumber(configFile>> "CfgVehicles" >> _unit >> "weaponSlots");
	_return = [];
	{
		_i = floor (_int / _x);
		_int = _int - (_i * _x);
		_return set [count _return, _i];
	} foreach [131072, 4096, 256, 16, 4, 2, 1];

	//_return = [%item slots%, %binocular slots%, %magazines%, %sidearm magazines%, %secondary weapons%, %sidearms%, %primary weapons%];
	_return
	
////////////////////////////////////////////////////

The crate idea is ingenious enough, and I've done it before, but I just wanted to make this one a while back, so I did :P.
Idea for you: If you don't want a crate, have a look at weaponHolders, it would dump your weapons in a pile (its what happens when you put down a weapon, as a weapon must be a cargo or being used, can't exist in object space), but at least that makes more sense then a crate.